DOpus Plus/DOpus Plus.iso/Enhancements/ImageConvert/ImageConvert.rexx

OS/2 REXX Batch file | 1998-10-13 | 15KB | 458 lines

/* $VER: ImageConvert.rexx 1.8 (13.10.98) (C) by Martin Steigerwald
*/

OPTIONS RESULTS

PARSE ARG files

SIGNAL ON SYNTAX
SIGNAL ON HALT
SIGNAL ON BREAK_C

handle=0
Initialize()
ConfigDialog()

appmode=UPPER(appmode)

maxfiles=0
DO UNTIL files=''
    files=STRIP(files)
    maxfiles=maxfiles+1
    IF LEFT(files,1)=='"' THEN DO
        PARSE VAR files '"' file.maxfiles '"' files
    END
    ELSE DO
        PARSE VAR files file.maxfiles ' ' files
    END /* IF */
END /* DO */

IF reqmode=='opus' THEN DO
    ADDRESS VALUE opusport
    DOPUS PROGRESS 'name bar abort'
    handle=RESULT
    IF handle>0 THEN DO
        DOPUS PROGRESS handle TITLE appname
    END
END

currentpath=PRAGMA('d')

DO i=1 TO maxfiles
    IF reqmode=='reqtools' THEN DO
        SAY 'Converting' file.i 'with' appmode 'to' destw 'x' desth '×' destcolors '...'
    END
    ELSE DO
        IF handle>0 THEN DO
            ADDRESS VALUE opusport
            DOPUS PROGRESS handle NAME file.i
            DOPUS PROGRESS handle ABORT
            IF RESULT=1 THEN LEAVE
            ADDRESS
        END
    END
    file=file.i
    IF POS(':', file)=0 THEN DO
        file=currentpath'/'file
    END
    CALL Convert(destw desth destcolors destformat appmode file)
    IF reqmode=='opus' & handle>0 THEN DO
        ADDRESS VALUE opusport
        DOPUS PROGRESS handle BAR maxfiles i
        ADDRESS
    END
END

Cleanup()
EXIT

syntax:
SAY 'Error:' rc',' ERRORTEXT(rc) 'in line' sigl'.'

break_c:
halt:
Cleanup()
EXIT

Cleanup:
IF handle~=0 THEN DO
    ADDRESS VALUE OPUSPORT
    DOPUS PROGRESS handle OFF
    ADDRESS
    handle=0
END
RETURN 0

EXIT

convert:
    PARSE ARG destw ' ' desth ' ' destcolors ' ' destformat ' 'appmode ' ' file

    IF EXISTS(file) THEN DO
        destfile=newext(destformat file)
        SELECT
            WHEN appmode=='PPAINT' THEN DO
                IF ~SHOW('P', 'PPAINT') THEN DO
                    ADDRESS COMMAND 'run >NIL: <NIL: PPaint:PPaint'
                    ADDRESS COMMAND 'WaitForPort PPAINT'
                END /* IF */
                ADDRESS PPAINT
                IF destcolors>256 THEN DO
                    destcolors=256
                END
                LockGUI
                Version REXX
                ver=RESULT
                LoadBrush 'FILE "'file'" FORCE QUIET NOPROGRESS'
                IF RC>0 THEN DO
                   request('"'getstr(100, 'OK')'"' getstr(4, 'Could not load file »%s«!',file))
                END
                ELSE DO
                    /* Shall I scale the picture? */
                    IF destw>0 THEN DO
                        IF ver>=8 THEN DO
                            GetCurrentBrush
                            currentbsh = RESULT
                            custombsh = (WORD(currentbsh, 1) = 'BRUSH')
                            IF custombsh THEN DO
                                SetBrushAttributes 'WIDTH' destw 'HEIGHT' desth 'COLORS' destcolors 'EXTENDPALETTE FORCE QUIET NOPROGRESS'
                            END
                            ELSE DO
                                request('"'getstr(100, 'OK')'"' getstr(4, 'Could not load file »%s«!',file))
                            END /* IF custombsh */
                        END
                        ELSE DO
                            SetBrushAttr 'WIDTH' destw 'HEIGHT' desth 'COLORS' destcolors 'FORCE QUIET NOPROGRESS'
                        END /* version check */
                    END
                    SaveBrush 'FILE "'destfile'" FORCE QUIET NOPROGRESS FORMAT' destformat
                END /* LoadBrush check */
                FreeBrush FORCE
                UnlockGUI
                ADDRESS
            END /* WHEN */
            WHEN appmode=='ARTEFFECT' THEN DO
                IF ~SHOW('P', 'ArtEffect') THEN DO
                    oldstack=PRAGMA('STACK', 30000)
                    ADDRESS COMMAND 'run >NIL: <NIL: ArtEffect:ArtEffect'
                    ADDRESS COMMAND 'WaitForPort ArtEffect'
                    dummy=PRAGMA('STACK', oldstack)
                END /* IF */
                ADDRESS "ArtEffect"
                ds=UPPER(destformat)
                IF ds=='ILBM' THEN DO
                    destaeformat='IFF-ILBM'
                END
                ELSE IF ds=='JPEG' THEN DO
                    destaeformat='JFIF-JPEG'
                END
                ELSE DO
                    destaeformat=ds
                END
                LOCKGUI
                LOADPIC 'NAME "' || file || '"'
                IF destw>0 THEN SCALEPIC destw desth
                SAVEPIC 'NAME "' || destfile || '" NOFLATTEN EXCLUDEALPHA PLUGIN ' destaeformat
                CLOSEPIC FORCE
                UNLOCKGUI
                ADDRESS
            END /* WHEN */
            WHEN appmode=='PHOTOGENICS2' THEN DO
                IF ~SHOW('P', 'PHOTOGENICS.1') THEN DO
                    oldstack=PRAGMA('STACK', 25000)
                    ADDRESS COMMAND 'run >NIL: <NIL: Photogenics:Photogenics'
                    ADDRESS COMMAND 'WaitForPort PHOTOGENICS.1'
                    dummy=PRAGMA('STACK', oldstack)
                END /* IF */
                ADDRESS PHOTOGENICS.1
                LOAD '"'file'"'
                buf=RESULT
                IF RC=0 THEN DO
                    IF destw>0 THEN SCALE buf destw desth 'SMOOTH'
                    ds=UPPER(destformat)
                    SELECT
                        WHEN ds=='JPEG' THEN DO
                            SAVE buf '"'ds'" "'destfile'" 80'
                        END
                        WHEN ds=='ILBM' THEN DO
                            ADDRESS
                            request('"OK"' 'Saving ILBM with Photogenics might not work yet.')
                            ADDRESS PHOTOGENICS.1
                            IF destcolors>256 THEN DO
                                destcolors=256
                            END
                            SAVE buf '"'ds'" "'destfile'"' destcolors
                        END
                        WHEN ds=='PNG' THEN DO
                            IF destcolors=16777216 THEN DO
                                destcolors='24BIT'
                            END
                            IF destcolors>2 & destcolors<16 THEN DO
                                destcolors=16
                            END
                            IF destcolors>16 & destcolors<256 THEN DO
                                destcolors=256
                            END
                            SAVE buf '"'ds'" "'destfile'"' destcolors
                        END
                        WHEN ds=='GIF' THEN DO
                            SAVE buf '"'ds'" "'destfile'"'
                        END
                        OTHERWISE NOP
                    END /* SELECT */
                    CLOSE buf
                END /* IF RC */
                ELSE DO
                    ADDRESS
                    request('"'getstr(100, 'OK')'"' getstr(4, 'Could not load file »%s«!',file))
                END /* IF buffer */
                ADDRESS
            END /* WHEN */
            OTHERWISE NOP
        END /* SELECT */
    END
    ELSE DO
        request('"'getstr(100, 'OK')'"' getstr(6,'File »%s« not found!',file))
    END /* IF EXISTS */
RETURN 0

SaveConfig:
    PARSE ARG saveit
    IF OPEN('fh', 'S:ImageConvert.cfg', 'W') THEN DO
        WRITELN('fh', 'ImageConvert')
        WRITELN('fh', appmode)
        WRITELN('fh', reqmode)
        WRITELN('fh', destformat)
        WRITELN('fh', destw)
        WRITELN('fh', desth)
        WRITELN('fh', destcolors)
        CLOSE('fh')
/*
        IF saveit=1 THEN DO
            ADDRESS COMMAND 'COPY <NIL: >NIL: ENV:ImageConvert.cfg ENVARC: QUIET CLONE NOREQ'
        END
*/
    END
    ELSE DO
        request('"'getstr(100, 'OK')'"' getstr(7, 'Could not save config file!'))
    END
RETURN 0

LoadConfig:
    IF OPEN('fh', 'S:ImageConvert.cfg', 'R') THEN DO
        IF READLN('fh')=='ImageConvert' THEN DO
            appmode=READLN('fh')
            reqmode=READLN('fh')
            destformat=READLN('fh')
            destw=READLN('fh')
            desth=READLN('fh')
            destcolors=READLN('fh')
        END
        CLOSE('fh')
    END
    ELSE DO
        appmode='PPaint'
        reqmode='opus'
        destformat='ILBM'
        destw=640
        desth=480
        destcolors=128
    END
RETURN 0

ConfigDialog:
    /* should I ask the user? */
    destc=destcolors
    IF destcolors=16777216 THEN destc='16M'
    /* destw=0 --> do not alter resolution! */
    IF destw~=0 THEN DO
        resolution=destw' x 'desth
    END
    ELSE DO
        resolution=getstr(210, 'As before')
    END
    res=request('"'getstr(102, 'Yes') || '|' || getstr(103, 'No') || '|' || getstr(101, 'Cancel')'"' getstr(200, 'Do you want to convert the image(s) as follows:') || lf || appmode' 'getstr(201, 'to')' 'UPPER(destformat)':'resolution' x 'destc'?')
    IF res=0 THEN EXIT
    /* ask the user */
    IF res=2 THEN DO
        /* reqmode */
        IF reqtools=1 & opus=1 THEN DO
            res=request('"DOpus|ReqTools|' || getstr(101, 'Cancel')'"' getstr(209, 'Which kind of requesters do you like?'))
            IF res=0 THEN EXIT
            IF res=1 THEN reqmode='opus'
            IF res=2 THEN reqmode='reqtools'
        END

        /* appmode */
        res=request('"ArtEffect|Photogenics2|PPaint|' || getstr(101, 'Cancel')'"' getstr(202, 'Which application do you want to use?'))
        IF res=0 THEN EXIT
        IF res=1 THEN appmode='ArtEffect'
        IF res=2 THEN appmode='Photogenics2'
        IF res=3 THEN appmode='PPaint'

        /* image format */
        formats='ILBM|JPEG|PNG|GIF|'
        IF appmode=='PPaint' THEN formats='ILBM|PNG|GIF|'
        IF appmode=='ArtEffect' THEN formats='ILBM|JPEG|PNG|'
        IF appmode=='Photogenics2' THEN formats='JPEG|PNG|GIF|'

        res=request('"'formats || getstr(101, 'Cancel')'"' getstr(206, 'Which formats should the converted image(s) have?'))
        IF res=0 THEN EXIT
        IF appmode=='PPaint' & res>1 THEN res=res+1
        IF appmode=='Photogenics2' THEN res=res+1
        IF res=1 THEN destformat='ilbm'
        IF res=2 THEN destformat='jpeg'
        IF res=3 THEN destformat='png'
        IF res=4 THEN destformat='gif'

        /* resolution */
        resw.1=640 ; resh.1=256
        resw.2=640 ; resh.2=480
        resw.3=800 ; resh.3=600
        resw.4=1024 ; resh.4=768
        resw.5=1280 ; resh.5=1024

        res=request('"640x256|640x480|800x600|1024x768|1280x1024|'getstr(210, 'As before')'|'getstr(204, 'Custom')'|'getstr(101, 'Cancel')'"' getstr(203, 'Which resolution do you want to use?'))
        IF res=0 THEN EXIT
        IF res=7 THEN DO
            DO UNTIL destw>0
                destw=numberrequest(getstr(100, 'OK') || '|' || getstr(101, 'Cancel') destw getstr(207, 'How wide should the converted image(s) be (in pixel)?'))
                IF destw=-1 THEN EXIT
            END
            DO UNTIL desth>0
                desth=numberrequest(getstr(100, 'OK') || '|' || getstr(101, 'Cancel') desth getstr(208, 'How high should the converted image(s) be (in pixel)?'))
                IF desth=-1 THEN EXIT
            END
        END
        ELSE IF res=6 THEN DO
            destw=0
        END
        ELSE DO
            destw=resw.res
            desth=resh.res
        END

        /* # of colors */
        destcolors=16777216
        IF appmode~=='ArtEffect' & destformat~=='jpeg' THEN DO
            colors='2|4|8|16|32|64|128|256|16M|'
            IF appmode=='PPaint' THEN colors='2|4|8|16|32|64|128|256|'
            destdepth=request('"'colors || getstr(101, 'Cancel')'"' getstr(205, 'How many colors should the converted image(s) have?'))
            IF destdepth=0 THEN EXIT
            IF destdepth=9 THEN destdepth=24
            destcolors=2**destdepth
        END /* IF appmode */

        SaveConfig()
    END
RETURN 0

newext: PROCEDURE EXPOSE opusport handle
    PARSE ARG destformat ' ' file
    p=LASTPOS('.',file)
    IF p>0 THEN file=LEFT(file,p-1)
    destfile = file || '.' || destformat
RETURN destfile

request: PROCEDURE EXPOSE reqmode opusport appname handle
    PARSE ARG '"'buttontext'" ' reqtext
    IF reqmode == 'opus' THEN DO
        ADDRESS VALUE opusport
        DOPUS REQUEST '"'reqtext'" 'buttontext
        res=RC
    END
    ELSE DO
        res=rtezrequest(reqtext, buttontext, appname)
    END
RETURN res

numberrequest: PROCEDURE EXPOSE reqmode opusport appname handle
    PARSE ARG buttontext ' ' oldvalue ' ' reqtext
    IF reqmode == 'opus' THEN DO
        ADDRESS VALUE opusport
        DO UNTIL DATATYPE(res)=='NUM'
            DOPUS GETSTRING '"' || reqtext || '" 40' oldvalue buttontext
            res=0
            IF RESULT~=='RESULT' THEN DO
                res=RESULT
            END
            ELSE DO
                res=-1
            END
        END
    END
    ELSE DO
        res=rtgetlong(oldvalue, reqtext, appname, buttontext, , buttonres)
        IF buttonres=0 THEN DO
            res=-1
        END
    END
RETURN res

getstr: PROCEDURE EXPOSE catalog opusport handle
    PARSE ARG msgno, msgstring
    IF catalog ~= 0 THEN msgstring = GetCatalogStr(catalog,msgno,msgstring)
    DO i = 3 TO ARG()
        PARSE VAR msgstring fore '%s' aft
        msgstring = fore||ARG(i)||aft
    END
RETURN msgstring

Initialize:
    appname='ImageConvert'
    lf='0a'x

    catalog=0
    locale=1
    IF ~SHOW('L', 'locale.library') THEN DO
        IF ~ADDLIB('locale.library',0,-30,0) THEN DO
            locale=0
        END
    END /* IF */

    IF locale=1 THEN catalog = OpenCatalog(appname'.catalog','english',2)

    IF ~SHOW('L','rexxsupport.library') THEN DO
        IF ~ADDLIB('rexxsupport.library',0,-30,0) THEN DO
            SAY GetStr(1,'Didnt find rexxsupport.library!')
            EXIT
        END
    END /* IF */

    LoadConfig()

    opus=0
    IF SHOW('P', 'DOPUS.1') THEN DO
        opusport='DOPUS.1'
        opus=1
    END
    ELSE DO
        reqmode='reqtools'
    END /* IF */

    reqtools=1
    IF ~SHOW('L', 'rexxreqtools.library') THEN DO
        IF ~ADDLIB('rexxreqtools.library', 0, -30, 0) THEN DO
            reqtools=0
            IF reqmode='reqtools' THEN DO
                IF opus=1 THEN DO
                    reqmode='opus'
                END
                ELSE DO
                    SAY GetStr(2, 'Didnt find DOpus or RexxReqTools for displaying requesters!')
                END
            END
        END
    END /* IF */

    IF files=='' THEN DO
        request('"'getstr(100, 'OK')'"' getstr(3,'I need some filenames of pictures to convert!'))
        EXIT
    END /* IF */

    /* no progress bar opened! */

    handle=0
RETURN 0